add lua language server using overlays

overlays/sumneko-lua-language-server/default.nix

@@ -0,0 +1,38 @@
+self: super: {
+  sumneko-lua-language-server = super.sumneko-lua-language-server.overrideAttrs (
+    o: rec {
+      version = "2.2.3";
+
+      src = builtins.fetchurl {
+        url = "https://github.com/sumneko/vscode-lua/releases/download/v${version}/lua-${version}.vsix";
+        sha256 = "16rpi6p7rslpdfi37ndy5g9qmvh22qljfk9w15kdrr668hfwp7nm";
+      };
+
+      unpackPhase = ''
+        ${super.pkgs.unzip}/bin/unzip $src
+      '';
+
+      platform = if super.stdenv.isDarwin then "macOS" else "Linux";
+
+      preBuild = "";
+      postBuild = "";
+      nativeBuildInputs = [
+        super.makeWrapper
+      ];
+
+      installPhase = ''
+        mkdir -p $out
+        cp -r extension $out/extras
+        chmod a+x $out/extras/server/bin/$platform/lua-language-server 
+        makeWrapper $out/extras/server/bin/$platform/lua-language-server \
+          $out/bin/lua-language-server \
+          --add-flags "-E -e LANG=en $out/extras/server/main.lua \
+          --logpath='~/.cache/sumneko_lua/log' \
+          --metapath='~/.cache/sumneko_lua/meta'"
+      '';
+
+      meta.platforms = super.lib.platforms.all;
+    }
+  );
+}
+